Tweener Blur Animation

I wrote up a couple classes to utilize a blur animation effect with the use of Tweener Actionscript Library

Here is the stripped down Main Document class:

package {
	import flash.display.Sprite;
	import flash.events.Event;

    public class Main extends Sprite {

		private var ba:BlurAnimation;

		public function Main()
		{
			addEventListener ( Event.ADDED_TO_STAGE , init );
        }

		private function init(e:Event):void
		{
			ba = new BlurAnimation( "http://manewc.com/projects/flash/i/gahlord.jpg", 400, 400, 5 );
			addChild(ba);

			ba.x = stage.stageWidth / 2 - 245;
			ba.y = stage.stageHeight / 2 - 245;
		}
    }
}

Here is the blur animation effect using the Tweener Class

package
{
	import flash.display.Sprite;
	import flash.net.URLRequest;
	import flash.filters.BlurFilter;
	import flash.filters.BitmapFilterQuality;
	import caurina.transitions.Tweener;

	public class BlurAnimation extends Sprite
	{
		private var back_mc:LoadImage;

		public function BlurAnimation(imgurl:String, xblur:Number=10, yblur:Number=10, timer:Number=1)
		{
			var filter:BlurFilter=new BlurFilter(xblur,yblur,BitmapFilterQuality.MEDIUM);
			var filters_array:Array=new Array();
			filters_array.push(filter);

			back_mc = new LoadImage(imgurl);
			addChild ( back_mc );

			back_mc.filters=filters_array;

			Tweener.addTween(back_mc,{_blur_blurX:0,_blur_blurY:0, time:timer});
		}
	}
}

A class I use to load in my images:

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoadImage extends Sprite {
        private var url:String;
		private var imageHolder:Sprite;
		public var LoadImageArray:Array = new Array();
		public var bits:Number;
		public var bitsLoaded:Number;
		public var totalBits:Number;
		// public var imgCompleted:Boolean;

        public function LoadImage(url:String) {

			var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);

			var request:URLRequest = new URLRequest( url );
            loader.load(request);

			imageHolder = new Sprite();
			addChild ( imageHolder );
            imageHolder.addChild(loader);

        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
			dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
			dispatcher.addEventListener(Event.COMPLETE, completeHandler);
        }

        private function completeHandler(event:Event):void {
			trace ( "image loaded complete");
		}

        private function progressHandler(event:ProgressEvent):void {
            trace ("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
    }
}