manewcActionscript Snippets

[AS 3] Papervision Cube with Different Material Sides

6 comments so far

Download Files (.zip)

So there was a request for an update to the Papervision cube that I did last week to allow for various materials on the 6 sides of the cube. I have noticed that there is a MaterialsList Class that allows you to addMaterials to your objects. I also found this a piece of code here:

http://kelvinluck.com/assets/papervision3d/cube_tweaks/

and also his updated Cube.as class file to be found here:

http://kelvinluck.com/assets/papervision3d/cube_tweaks/Cube.as

Here is my cube that pulls one image from the library with the class name of CubeTexture, loads an external image, and randomly chooses a color for the remaining sides of the cube.

Here is my document class:

package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.materials.BitmapMaterial;
	import org.papervision3d.materials.BitmapFileMaterial;
	import org.papervision3d.materials.MaterialsList;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.objects.Collada;
	import org.papervision3d.core.proto.DisplayObjectContainer3D;
	import org.papervision3d.objects.Cube;
	import org.papervision3d.materials.ColorMaterial;

	public class PapervisionCubeSides extends Sprite
	{
		// image 1 variable represents an image in the library with the class name of CubeTexture
		private var image1:BitmapData = new CubeTexture(0,0);
		private var container:Sprite;
		private var scene:Scene3D;
		private var camera:Camera3D;
		private var rootNode:DisplayObject3D;
		private var ml:MaterialsList = new MaterialsList();
		private var customcube:Cube;

		public function PapervisionCubeSides()
		{
			init3D();
			addEventListener(Event.ENTER_FRAME, Timeline);
		}

		private function init3D():void {
			container = new Sprite();
			addChild( container );
			container.x = stage.stageWidth * .5;
			container.y = stage.stageHeight * .5;
			scene = new Scene3D( container );
			camera = new Camera3D();
			camera.zoom = 10;

			rootNode = scene.addChild( new DisplayObject3D("rootNode") );

			var ml:MaterialsList = new MaterialsList();
			ml.addMaterial(new BitmapFileMaterial("http://manewc.com/projects/flash/PapervisionCubeSides/ski.jpg"), 'face1');
			ml.addMaterial(new BitmapMaterial( image1 ), 'face2');
			ml.addMaterial(new BitmapFileMaterial("http://manewc.com/projects/flash/PapervisionCubeSides/ski.jpg"), 'face3');
			ml.addMaterial(new BitmapMaterial( image1 ), 'face4');
			ml.addMaterial(new ColorMaterial(Math.random()*0xffffff), 'face5');
			ml.addMaterial(new ColorMaterial(Math.random()*0xffffff), 'face6');

			customcube = new Cube( ml, 200, 200, 200, 1, 1, 1 );
			rootNode.addChild( customcube, "myCube01" );
		}

		private function Timeline( event:Event ):void {
			var screen:DisplayObject3D = this.scene.getChildByName("rootNode");
			var rotationY:Number = -(this.mouseX / this.stage.stageWidth * 275);
			var rotationX:Number = -(this.mouseY / this.stage.stageHeight * 275);
			screen.rotationY += (rotationY - screen.rotationY) / 12;
			screen.rotationX += (rotationX - screen.rotationX) / 12;

			this.scene.renderCamera(this.camera);
		}
	}
}

Monday, March 24th, 2008 at 8:20 am and is filed under Actionscript 3, Papervision. You can follow any responses to this entry through the RSS 2.0 feed. You can leave a response, or trackback from your own site.